package tezos-protocol-alpha

You can search for identifiers within the package.
in-package search v0.2.0
tezos-protocol-alpha
Legend:
Page
Library
Module
Module type
Parameter
Class
Class type
Source
Source file `contract_manager_storage.ml`

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
(*****************************************************************************)
(*                                                                           *)
(* Open Source License                                                       *)
(* Copyright (c) 2021 Nomadic Labs, <contact@nomadic-labs.com>               *)
(*                                                                           *)
(* Permission is hereby granted, free of charge, to any person obtaining a   *)
(* copy of this software and associated documentation files (the "Software"),*)
(* to deal in the Software without restriction, including without limitation *)
(* the rights to use, copy, modify, merge, publish, distribute, sublicense,  *)
(* and/or sell copies of the Software, and to permit persons to whom the     *)
(* Software is furnished to do so, subject to the following conditions:      *)
(*                                                                           *)
(* The above copyright notice and this permission notice shall be included   *)
(* in all copies or substantial portions of the Software.                    *)
(*                                                                           *)
(* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR*)
(* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,  *)
(* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL   *)
(* THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER*)
(* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING   *)
(* FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER       *)
(* DEALINGS IN THE SOFTWARE.                                                 *)
(*                                                                           *)
(*****************************************************************************)

type error +=
  | (* `Branch *) Unrevealed_manager_key of Contract_repr.t
  | (* `Permanent *)
      Inconsistent_hash of {
      public_key : Signature.Public_key.t;
      expected_hash : Signature.Public_key_hash.t;
      provided_hash : Signature.Public_key_hash.t;
    }
  | (* `Branch *) Previously_revealed_key of Contract_repr.t
  | (* `Branch *) Missing_manager_contract of Contract_repr.t

let () =
  register_error_kind
    `Branch
    ~id:"contract.unrevealed_key"
    ~title:"Manager operation precedes key revelation"
    ~description:
      "One tried to apply a manager operation without revealing the manager \
       public key"
    ~pp:(fun ppf s ->
      Format.fprintf
        ppf
        "Unrevealed manager key for contract %a."
        Contract_repr.pp
        s)
    Data_encoding.(obj1 (req "contract" Contract_repr.encoding))
    (function Unrevealed_manager_key s -> Some s | _ -> None)
    (fun s -> Unrevealed_manager_key s) ;
  register_error_kind
    `Permanent
    ~id:"contract.manager.inconsistent_hash"
    ~title:"Inconsistent public key hash"
    ~description:
      "A revealed manager public key is inconsistent with the announced hash"
    ~pp:(fun ppf (k, eh, ph) ->
      Format.fprintf
        ppf
        "The hash of the manager public key %s is not %a as announced but %a"
        (Signature.Public_key.to_b58check k)
        Signature.Public_key_hash.pp
        ph
        Signature.Public_key_hash.pp
        eh)
    Data_encoding.(
      obj3
        (req "public_key" Signature.Public_key.encoding)
        (req "expected_hash" Signature.Public_key_hash.encoding)
        (req "provided_hash" Signature.Public_key_hash.encoding))
    (function
      | Inconsistent_hash {public_key; expected_hash; provided_hash} ->
          Some (public_key, expected_hash, provided_hash)
      | _ -> None)
    (fun (public_key, expected_hash, provided_hash) ->
      Inconsistent_hash {public_key; expected_hash; provided_hash}) ;
  register_error_kind
    `Branch
    ~id:"contract.previously_revealed_key"
    ~title:"Manager operation already revealed"
    ~description:"One tried to reveal twice a manager public key"
    ~pp:(fun ppf s ->
      Format.fprintf
        ppf
        "Previously revealed manager key for contract %a."
        Contract_repr.pp
        s)
    Data_encoding.(obj1 (req "contract" Contract_repr.encoding))
    (function Previously_revealed_key s -> Some s | _ -> None)
    (fun s -> Previously_revealed_key s) ;
  register_error_kind
    `Branch
    ~id:"contract.missing_manager_contract"
    ~title:"Missing manager contract"
    ~description:"The manager contract is missing from the storage"
    ~pp:(fun ppf s ->
      Format.fprintf
        ppf
        "The contract %a is missing from the storage."
        Contract_repr.pp
        s)
    Data_encoding.(obj1 (req "contract" Contract_repr.encoding))
    (function Missing_manager_contract s -> Some s | _ -> None)
    (fun s -> Missing_manager_contract s)

let init = Storage.Contract.Manager.init

let is_manager_key_revealed c manager =
  let open Lwt_result_syntax in
  let contract = Contract_repr.Implicit manager in
  let* key_opt = Storage.Contract.Manager.find c contract in
  match key_opt with
  | None -> return_false
  | Some (Manager_repr.Hash _) -> return_false
  | Some (Manager_repr.Public_key _) -> return_true

let check_public_key public_key expected_hash =
  let provided_hash = Signature.Public_key.hash public_key in
  error_unless
    (Signature.Public_key_hash.equal provided_hash expected_hash)
    (Inconsistent_hash {public_key; expected_hash; provided_hash})

let reveal_manager_key ?(check_consistency = true) c manager public_key =
  let open Lwt_result_syntax in
  let contract = Contract_repr.Implicit manager in
  let* key_opt = Storage.Contract.Manager.get c contract in
  match key_opt with
  | Public_key _ -> tzfail (Previously_revealed_key contract)
  | Hash expected_hash ->
      (* Ensure that the manager is equal to the retrieved hash. *)
      let*? () =
        error_unless
          (Signature.Public_key_hash.equal manager expected_hash)
          (Inconsistent_hash
             {public_key; expected_hash; provided_hash = manager})
      in
      (* TODO tezos/tezos#3078

         We keep the consistency check and the optional argument to
         preserve the semantics of reveal_manager_key prior to
         tezos/tezos!5182, when called outside the scope of
         [apply_operation].

         Inside appply.ml, it is used with
         ?check_consistency=false. Ultimately this parameter should go
         away, and the split check_publick_key / reveal_manager_key
         pattern has to be exported to usage outside apply.ml *)
      let* () =
        when_ check_consistency (fun () ->
            Lwt.return @@ check_public_key public_key expected_hash)
      in
      let pk = Manager_repr.Public_key public_key in
      Storage.Contract.Manager.update c contract pk

let get_manager_key ?error ctxt pkh =
  let open Lwt_result_syntax in
  let contract = Contract_repr.Implicit pkh in
  let* key_opt = Storage.Contract.Manager.find ctxt contract in
  match key_opt with
  | None -> (
      match error with
      | None -> tzfail (Missing_manager_contract contract)
      | Some error -> tzfail error)
  | Some (Manager_repr.Hash _) -> (
      match error with
      | None -> tzfail (Unrevealed_manager_key contract)
      | Some error -> tzfail error)
  | Some (Manager_repr.Public_key pk) -> return pk

let remove_existing = Storage.Contract.Manager.remove_existing
package tezos-protocol-alpha

Source file contract_manager_storage.ml

Source file `contract_manager_storage.ml`
