Representation of types and declarations

Types defines the representation of types and declarations (that is, the content of module signatures).

CMI files are made of marshalled types.

Asttypes exposes basic definitions shared both by Parsetree and Types.

type type_expr

Type expressions for the core language.

The type_desc variant defines all the possible type expressions one can find in OCaml. type_expr wraps this with some annotations.

The level field tracks the level of polymorphism associated to a type, guiding the generalization algorithm. Put shortly, when referring to a type in a given environment, both the type and the environment have a level. If the type has an higher level, then it can be considered fully polymorphic (type variables will be printed as 'a), otherwise it'll be weakly polymorphic, or non generalized (type variables printed as '_a). See http://okmij.org/ftp/ML/generalization.html for more information.

Note about type_declaration: one should not make the confusion between type_expr and type_declaration.

type_declaration refers specifically to the type construct in OCaml language, where you create and name a new type or type alias.

type_expr is used when you refer to existing types, e.g. when annotating the expected type of a value.

Also, as the type system of OCaml is generative, a type_declaration can have the side-effect of introducing a new type constructor, different from all other known types. Whereas type_expr is a pure construct which allows referring to existing types.

Note on mutability: TBD.

type row_desc

type row_field

type field_kind

type commutable

type type_desc =

| Tvar of string option
(*
Tvar (Some "a") ==> 'a or '_a Tvar None ==> _
*)
| Tarrow of Asttypes.arg_label * type_expr * type_expr * commutable
(*
Tarrow (Nolabel, e1, e2, c) ==> e1 -> e2 Tarrow (Labelled "l", e1, e2, c) ==> l:e1 -> e2 Tarrow (Optional "l", e1, e2, c) ==> ?l:e1 -> e2
See commutable for the last argument.
*)
| Ttuple of type_expr list
(*
Ttuple [t1;...;tn] ==> (t1 * ... * tn)
*)
| Tconstr of Path.t * type_expr list * abbrev_memo ref
(*
Tconstr (`A.B.t', [t1;...;tn], _) ==> (t1,...,tn) A.B.t The last parameter keep tracks of known expansions, see abbrev_memo.
*)
| Tobject of type_expr * (Path.t * type_expr list) option ref
(*
Tobject (`f1:t1;...;fn: tn', `None') ==> < f1: t1; ...; fn: tn > f1, fn are represented as a linked list of types using Tfield and Tnil constructors.
Tobject (_, `Some (`A.ct', [t1;...;tn]') ==> (t1, ..., tn) A.ct. where A.ct is the type of some class.
There are also special cases for so-called "class-types", cf. Typeclass and Ctype.set_object_name:
Tobject (Tfield(_,_,...(Tfield(_,_,rv)...), Some(`A.#ct`, [rv;t1;...;tn]) ==> (t1, ..., tn) #A.ct Tobject (_, Some(`A.#ct`, [Tnil;t1;...;tn]) ==> (t1, ..., tn) A.ct
where rv is the hidden row variable.
*)
| Tfield of string * field_kind * type_expr * type_expr
(*
Tfield ("foo", field_public, t, ts) ==> <...; foo : t; ts>
*)
| Tnil
(*
Tnil ==> <...; >
*)
| Tlink of type_expr
(*
Indirection used by unification engine.
*)
| Tsubst of type_expr * type_expr option
(*
Tsubst is used temporarily to store information in low-level functions manipulating representation of types, such as instantiation or copy. The first argument contains a copy of the original node. The second is available only when the first is the row variable of a polymorphic variant. It then contains a copy of the whole variant. This constructor should not appear outside of these cases.
*)
| Tvariant of row_desc
(*
Representation of polymorphic variants, see row_desc.
*)
| Tunivar of string option
(*
Occurrence of a type variable introduced by a forall quantifier / Tpoly.
*)
| Tpoly of type_expr * type_expr list
(*
Tpoly (ty,tyl) ==> 'a1... 'an. ty, where 'a1 ... 'an are names given to types in tyl and occurrences of those types in ty.
*)
| Tpackage of Path.t * (Longident.t * type_expr) list
(*
Type of a first-class module (a.k.a package).
*)

and fixed_explanation =

| Univar of type_expr
(*
The row type was bound to an univar
*)
| Fixed_private
(*
The row type is private
*)
| Reified of Path.t
(*
The row was reified
*)
| Rigid
(*
The row type was made rigid during constraint verification
*)

and abbrev_memo =

| Mnil
(*
No known abbreviation
*)
| Mcons of Asttypes.private_flag * Path.t * type_expr * type_expr * abbrev_memo
(*
Found one abbreviation. A valid abbreviation should be at least as visible and reachable by the same path. The first expression is the abbreviation and the second the expansion.
*)
| Mlink of abbrev_memo ref
(*
Abbreviations can be found after this indirection
*)

abbrev_memo allows one to keep track of different expansions of a type alias. This is done for performance purposes.

For instance, when defining type 'a pair = 'a * 'a, when one refers to an 'a pair, it is just a shortcut for the 'a * 'a type. This expansion will be stored in the abbrev_memo of the corresponding Tconstr node.

In practice, abbrev_memo behaves like list of expansions with a mutable tail.

Note on marshalling: abbrev_memo must not appear in saved types. Btype, with cleanup_abbrev and memo, takes care of tracking and removing abbreviations.

commutable is a flag appended to every arrow type.

When typing an application, if the type of the functional is known, its type is instantiated with commu_ok arrows, otherwise as commu_var ().

When the type is not known, the application will be used to infer the actual type. This is fragile in presence of labels where there is no principal type.

Two incompatible applications must rely on is_commu_ok arrows, otherwise they will trigger an error.

let f g = g ~a:() ~b:(); g ~b:() ~a:();

Error: This function is applied to arguments in an order different from other calls. This is only allowed when the real type is known.

val is_commu_ok : commutable -> bool

val commu_ok : commutable

val commu_var : unit -> commutable

field_kind indicates the accessibility of a method.

An Fprivate field may become Fpublic or Fabsent during unification, but not the other way round.

The same field_kind is kept shared when copying Tfield nodes so that the copies of the self-type of a class share the same accessibility (see also PR#10539).

type field_kind_view =

| Fprivate
| Fpublic
| Fabsent

val field_kind_repr : field_kind -> field_kind_view

val field_public : field_kind

val field_absent : field_kind

val field_private : unit -> field_kind

val field_kind_internal_repr : field_kind -> field_kind

Getters for type_expr; calls repr before answering a value

val get_desc : type_expr -> type_desc

val get_level : type_expr -> int

val get_scope : type_expr -> int

val get_id : type_expr -> int

type transient_expr = private {

mutable desc : type_desc;
mutable level : int;
mutable scope : int;
id : int;

}

Transient type_expr. Should only be used immediately after Transient_expr.repr

module Transient_expr : sig ... end

Operations on transient_expr

val create_expr : type_desc -> level:int -> scope:int -> id:int -> type_expr

Functions and definitions moved from Btype

val newty3 : level:int -> scope:int -> type_desc -> type_expr

Create a type with a fresh id

val newty2 : level:int -> type_desc -> type_expr

Create a type with a fresh id and no scope

module TransientTypeOps : sig ... end

Comparisons for functors

Comparisons for type_expr; cannot be used for functors

val eq_type : type_expr -> type_expr -> bool

val compare_type : type_expr -> type_expr -> int

Constructor and accessors for row_desc

`X | `Y (row_closed = true) < `X | `Y (row_closed = true) > `X | `Y (row_closed = false) < `X | `Y > `X (row_closed = true)

type t = > `X as 'a (row_more = Tvar a) type t = private > `X (row_more = Tconstr ("t#row", , ref Mnil))

And for:

let f = function `X -> `X -> | `Y -> `X

the type of "f" will be a Tarrow whose lhs will (basically) be:

Tvariant row_fields = [("X", _)]; row_more = Tvariant { row_fields = [("Y", _)]; row_more = Tvariant { row_fields = []; row_more = _; _; _

}

; _

}

val create_row : 
  fields:(Asttypes.label * row_field) list ->
  more:type_expr ->
  closed:bool ->
  fixed:fixed_explanation option ->
  name:(Path.t * type_expr list) option ->
  row_desc

val row_fields : row_desc -> (Asttypes.label * row_field) list

val row_more : row_desc -> type_expr

val row_closed : row_desc -> bool

val row_fixed : row_desc -> fixed_explanation option

val row_name : row_desc -> (Path.t * type_expr list) option

val set_row_name : row_desc -> (Path.t * type_expr list) option -> row_desc

val get_row_field : Asttypes.label -> row_desc -> row_field

type row_desc_repr =

| Row of {
1. fields : (Asttypes.label * row_field) list;
2. more : type_expr;
3. closed : bool;
4. fixed : fixed_explanation option;
5. name : (Path.t * type_expr list) option;
}

get all fields at once; different from the old row_repr

val row_repr : row_desc -> row_desc_repr

type row_field_view =

| Rpresent of type_expr option
| Reither of bool * type_expr list * bool
| Rabsent

Current contents of a row field

val row_field_repr : row_field -> row_field_view

val rf_present : type_expr option -> row_field

val rf_absent : row_field

val rf_either : 
  ?use_ext_of:row_field ->
  no_arg:bool ->
  type_expr list ->
  matched:bool ->
  row_field

val rf_either_of : type_expr option -> row_field

val eq_row_field_ext : row_field -> row_field -> bool

val changed_row_field_exts : row_field list -> (unit -> unit) -> bool

val match_row_field : 
  present:(type_expr option -> 'a) ->
  absent:(unit -> 'a) ->
  either:(bool -> type_expr list -> bool -> row_field option -> 'a) ->
  row_field ->
  'a

module Uid = Shape.Uid

module MethSet : Set.S with type elt = string

module VarSet : Set.S with type elt = string

module Meths : Map.S with type key = string

module Vars : Map.S with type key = string

type value_description = {

val_type : type_expr;
val_kind : value_kind;
val_loc : Location.t;
val_attributes : Parsetree.attributes;
val_uid : Uid.t;

}

and value_kind =

| Val_reg
| Val_prim of Primitive.description
| Val_ivar of Asttypes.mutable_flag * string
| Val_self of class_signature * self_meths * Ident.t Vars.t * string
| Val_anc of class_signature * Ident.t Meths.t * string

and self_meths =

| Self_concrete of Ident.t Meths.t
| Self_virtual of Ident.t Meths.t ref

and class_signature = {

csig_self : type_expr;
mutable csig_self_row : type_expr;
mutable csig_vars : (Asttypes.mutable_flag * Asttypes.virtual_flag * type_expr) Vars.t;
mutable csig_meths : (method_privacy * Asttypes.virtual_flag * type_expr) Meths.t;

}

and method_privacy =

| Mpublic
| Mprivate of field_kind

module Variance : sig ... end

module Separability : sig ... end

see Typedecl_separability for an explanation of separability and separability modes.

type type_declaration = {

type_params : type_expr list;
type_arity : int;
type_kind : type_decl_kind;
type_private : Asttypes.private_flag;
type_manifest : type_expr option;
type_variance : Variance.t list;
type_separability : Separability.t list;
type_is_newtype : bool;
type_expansion_scope : int;
type_loc : Location.t;
type_attributes : Parsetree.attributes;
type_immediate : Type_immediacy.t;
type_unboxed_default : bool;
type_uid : Uid.t;

}

and type_decl_kind = (label_declaration, constructor_declaration) type_kind

and ('lbl, 'cstr) type_kind =

| Type_abstract
| Type_record of 'lbl list * record_representation
| Type_variant of 'cstr list * variant_representation
| Type_open

and record_representation =

| Record_regular
| Record_float
| Record_unboxed of bool
| Record_inlined of int
| Record_extension of Path.t

and variant_representation =

| Variant_regular
| Variant_unboxed

and label_declaration = {

ld_id : Ident.t;
ld_mutable : Asttypes.mutable_flag;
ld_type : type_expr;
ld_loc : Location.t;
ld_attributes : Parsetree.attributes;
ld_uid : Uid.t;

}

and constructor_declaration = {

cd_id : Ident.t;
cd_args : constructor_arguments;
cd_res : type_expr option;
cd_loc : Location.t;
cd_attributes : Parsetree.attributes;
cd_uid : Uid.t;

}

and constructor_arguments =

| Cstr_tuple of type_expr list
| Cstr_record of label_declaration list

type extension_constructor = {

ext_type_path : Path.t;
ext_type_params : type_expr list;
ext_args : constructor_arguments;
ext_ret_type : type_expr option;
ext_private : Asttypes.private_flag;
ext_loc : Location.t;
ext_attributes : Parsetree.attributes;
ext_uid : Uid.t;

}

and type_transparence =

| Type_public
| Type_new
| Type_private

type class_type =

| Cty_constr of Path.t * type_expr list * class_type
| Cty_signature of class_signature
| Cty_arrow of Asttypes.arg_label * type_expr * class_type

type class_declaration = {

cty_params : type_expr list;
mutable cty_type : class_type;
cty_path : Path.t;
cty_new : type_expr option;
cty_variance : Variance.t list;
cty_loc : Location.t;
cty_attributes : Parsetree.attributes;
cty_uid : Uid.t;

}

type class_type_declaration = {

clty_params : type_expr list;
clty_type : class_type;
clty_path : Path.t;
clty_variance : Variance.t list;
clty_loc : Location.t;
clty_attributes : Parsetree.attributes;
clty_uid : Uid.t;

}

type visibility =

| Exported
| Hidden

type module_type =

| Mty_ident of Path.t
| Mty_signature of signature
| Mty_functor of functor_parameter * module_type
| Mty_alias of Path.t

and functor_parameter =

| Unit
| Named of Ident.t option * module_type

and module_presence =

| Mp_present
| Mp_absent

and signature = signature_item list

and signature_item =

| Sig_value of Ident.t * value_description * visibility
| Sig_type of Ident.t * type_declaration * rec_status * visibility
| Sig_typext of Ident.t * extension_constructor * ext_status * visibility
| Sig_module of Ident.t * module_presence * module_declaration * rec_status * visibility
| Sig_modtype of Ident.t * modtype_declaration * visibility
| Sig_class of Ident.t * class_declaration * rec_status * visibility
| Sig_class_type of Ident.t * class_type_declaration * rec_status * visibility

and module_declaration = {

md_type : module_type;
md_attributes : Parsetree.attributes;
md_loc : Location.t;
md_uid : Uid.t;

}

and modtype_declaration = {

mtd_type : module_type option;
mtd_attributes : Parsetree.attributes;
mtd_loc : Location.t;
mtd_uid : Uid.t;

}

and rec_status =

| Trec_not
| Trec_first
| Trec_next

and ext_status =

| Text_first
| Text_next
| Text_exception

val item_visibility : signature_item -> visibility

type constructor_description = {

cstr_name : string;
cstr_res : type_expr;
cstr_existentials : type_expr list;
cstr_args : type_expr list;
cstr_arity : int;
cstr_tag : constructor_tag;
cstr_consts : int;
cstr_nonconsts : int;
cstr_generalized : bool;
cstr_private : Asttypes.private_flag;
cstr_loc : Location.t;
cstr_attributes : Parsetree.attributes;
cstr_inlined : type_declaration option;
cstr_uid : Uid.t;

}

and constructor_tag =

| Cstr_constant of int
| Cstr_block of int
| Cstr_unboxed
| Cstr_extension of Path.t * bool

val equal_tag : constructor_tag -> constructor_tag -> bool

val may_equal_constr : 
  constructor_description ->
  constructor_description ->
  bool

type label_description = {

lbl_name : string;
lbl_res : type_expr;
lbl_arg : type_expr;
lbl_mut : Asttypes.mutable_flag;
lbl_pos : int;
lbl_all : label_description array;
lbl_repres : record_representation;
lbl_private : Asttypes.private_flag;
lbl_loc : Location.t;
lbl_attributes : Parsetree.attributes;
lbl_uid : Uid.t;

}

val bound_value_identifiers : signature -> Ident.t list

Extracts the list of "value" identifiers bound by a signature. "Value" identifiers are identifiers for signature components that correspond to a run-time value: values, extensions, modules, classes. Note: manifest primitives do not correspond to a run-time value!

val signature_item_id : signature_item -> Ident.t

type snapshot

val snapshot : unit -> snapshot

val backtrack : cleanup_abbrev:(unit -> unit) -> snapshot -> unit

val undo_first_change_after : snapshot -> unit

val undo_compress : snapshot -> unit

Functions to use when modifying a type (only Ctype?). The old values are logged and reverted on backtracking.

val link_type : type_expr -> type_expr -> unit

val set_type_desc : type_expr -> type_desc -> unit

val set_level : type_expr -> int -> unit

val set_scope : type_expr -> int -> unit

val set_name : 
  (Path.t * type_expr list) option ref ->
  (Path.t * type_expr list) option ->
  unit

val link_row_field_ext : inside:row_field -> row_field -> unit

val set_univar : type_expr option ref -> type_expr -> unit

val link_kind : inside:field_kind -> field_kind -> unit

val link_commu : inside:commutable -> commutable -> unit

val set_commu_ok : commutable -> unit

package ocaml-base-compiler

Representation of types and declarations